KBS Course, lecture 03

Discrete age-structured model

Outline
-Leslie matrix
-Stable age distribution
-Projection matrix, Eigenvalues, Eigenvectors
-Lifetime reproductive success
-[Problem set: stage distribution]

Leslie matrix

Names after Patrick Leslie (1945). Describes mortality and fecundity for each age.

Imagine a population of fish. Draw out diagram

Draw table headings of Age, Age-specific Survival, Fecundity. Ask students to fill in table.

Age	Survival	Fecundity	
0	0.5		0
1	0.8		1
2	0.5		3
3	0		2

We are going to use the tools of matrix algebra, or linear algebra.

Vector:

MatrixForm[{20,30,8}]

A vector multiplied by a scalar, i.e. a single number:

0.5{20,30,8}//MatrixForm

Matrix:

MatrixForm[{{0.1,0.2,0.3},{0.5,0.7,0.3},{0.1,0.3,0.8}}]

In biology, typically square, i.e. same length and width. Used to change, or transform, a vector.

A vector multiplied by a matrix, i.e. matrix multiplication (also called dot product and inner product):

MatrixForm[{{0.1,0.2,0.3},{0.5,0.7,0.3},{0.1,0.3,0.8}}]. MatrixForm[{20,30,8}]

Rotate the vector, multiply pairwise for a row, and sum.

MatrixForm[{"0.1 * 20 + 0.2 * 30 + 0.3 * 8","0.5 * 20 + 0.7 * 30 + 0.3 * 8", "0.1 * 20 + 0.3 * 30 + 0.8 *8"}]

MatrixForm[{{0.1,0.2,0.3},{0.5,0.7,0.3},{0.1,0.3,0.8}}.{20,30,8}]

A new vector results. The original has been “transformed” by the matrix. Note that order matters, unlike scalar multiplication.

Identity Matrix, so called because the result of the dot product is the original vector:

IdentityMatrix[3]//MatrixForm

IdentityMatrix[3].{20,30,8}//MatrixForm

How can we put these numbers into a format to use these tools? A Leslie matrix. Place age-specific survival on the diagonal, and add a row of fecundity across the top (leaving off last 0 survival to keep square):

MatrixForm[{{"(Subscript[F, 0])","(Subscript[F, 1])","(Subscript[F, 2])"},{"(Subscript[P, 0])",0,0},{0,"(Subscript[P, 1])",0}}]

What is the Leslie Matrix for our population above?

MatrixForm[{{0,1,3,2},{0.5,0,0,0},{0,0.8,0,0},{0,0,0.5,0}}]

Read it “down and over”. In other words, each column describes how the age class of that column contributes to the age classes of the rows in the next time step.

MatrixForm[{{0,1,3,2},{0.5,0,0,0},{0,0.8,0,0},{0,0,0.5,0}}].MatrixForm[{20,30,10,8}]

MatrixForm[{{0,1,3,2},{0.5,0,0,0},{0,0.8,0,0},{0,0,0.5,0}}.{20,30,10,8}]

Use Mathematica to plot each age class over time. 
	Dot product is a period.

m={{0,1,3,2},{0.5,0,0,0},{0,0.8,0,0},{0,0,0.5,0}};
n={20,30,10,8};

m.n

The power of a matrix is defined as (M^2) = M.M, i.e. the dot product. Note, this is not just squaring each entry. In Mathematica, have to use the MatrixPower[] function.

MatrixPower[m,2]//MatrixForm

m.m.n

MatrixPower[m,2].n

{n,MatrixPower[m,1].n,MatrixPower[m,2].n}

Use ListLinePlot in combination with Transpose to plot each age class over time.

ListLinePlot[Transpose[{n,MatrixPower[m,1].n,MatrixPower[m,2].n}]]

Use the Table[] function to make this flexible

ListLinePlot[Transpose[Table[MatrixPower[m,i].n,{i,0,10}]]]

Ln the output

ListLinePlot[Log[Transpose[Table[MatrixPower[m,i].n,{i,0,10}]]]]

Now one can see the stable age distribution.
Question for students: How is this population growing. Answer: geometrically.

So we can ask what is the equivalent growth rate of the sum across all age classes?

a=Transpose[Table[MatrixPower[m,i].n,{i,0,10}]];
b=Join[{Total[a]},a];
p1=ListLinePlot[Log[b],PlotStyle->Prepend[ColorData[97,"ColorList"],Black]]

Eigenvalues[m]

f[x_]:=1.29177 x

p2=ListPlot[Log[NestList[f,Total[n],10]]]

Show[p1,p2]

And what is the proportion in the stable age distribution?

MatrixPower[m,20].n/Total[MatrixPower[m,20].n]

c=Eigenvectors[m][[1]];
c/Total[c]//Re

The dominant eigenvalue describes the asymptotic rate of expansion/contraction and the corresponding eigenvector describes how it expands/contracts.

Note the transient dynamics.

Lifetime reproductive success

Calculate survivorship, which is the fraction that survive to a given age.

Age	Survival	Survivorship	Fecundity	
0	0.5		1			0
1	0.8		0.5			1
2	0.5		0.4			3
3	0		0.2			2

Ask students to calculate the lifetime reproductive success, or net reproductive rate, 
((Subscript[R, 0])): 1 x 0 + 0.5 x 1 + 0.4 x 3 + 0.2 x 2 = 1.2

Problem set

We will extend the idea of age-structured populations to a stage-structured population. A number of conservation-based studies examine the age or stage structure of a population in order to understand the dynamics of the population.  Here, we will use the results of one such study on killer whales to build a simple model. 

reference:
Brault, S. and H. Caswell. 1993. Pod-specific demography of killer whales (Orcinus orca). Ecology 74:1444-1454.

Female killer whales have four major life stages: yearlings, juveniles, reproductive adults, and post-reproductuve adults.

1) Draw a diagram of the four stages, with arrows showing possible transitions between these stages.  Assume the time interval of our model is one year, so all yearlings that survive for one year transition into the juvenile stage.  However, killer whales can remain in the other three stages for multiple years.  Finally, the occasional juvenile will reproduce during the interval between model years because the real population can reproduce continuously

2) Create a simple system of difference equations to describe the model.  Assume simple linear relationships for all transitions, in other words density-independent.

3) Now use matrix notation to represent this system. Use letters to represent non-zero transitions while using zeros as appropriate.

4) Here are the matrix enteries from the Brault and Caswell paper.  The fecundity of juveniles is 0.0043.  The fecundity of adults is 0.1132.  The survivorship of yearlings to juveniles is 0.9775.  Juveniles remain juveniles with a probability of 0.9111 and become reproductive adults with a probability of 0.0736.  Reproductive adults remain reproductive adults with a probability of 0.9534 and become post-reproductive adults with a probability of 0.0452.  Post-reproductive adults remain post-reproductive adults with a probability of 0.9804.  Now you should be able to calculate the eigenvalues.

 5)Start the population with a small number of individuals as yearlings and no individuals in the other states.  Using the projection matrix, plot the number of individuals in each category across time.
 
 6) Calculate the stable stage distribution