A consumer-resource model with a biotic resource can be used to derive a logistic-style single-species model.  A consumer-resource model with an abiotic resource can be used to derive a Smith, or Monod-style, single species model.

Abiotic Resource

Full Model

((d R)/(d t))=k-β R-α R C
((d C)/(d t))=b α R C-m C

Manipulate[
ans=NDSolve[{r'[t]==k-β r[t]-α r[t] c[t],c'[t]==b α r[t] c[t]-m c[t],r[0]==init[[1,2]],c[0]==init[[2,2]]},{r,c},{t,0,tmax}];
Plot[Evaluate[{r[t],c[t]}/.ans],{t,0,tmax},PlotRange->{0,3}],
Style["Abiotic Resource",Bold],Delimiter,
{{k,1},0.01,10},
{{b,1},0.01,3},
{{β,0.8},0.01,3},
{{α,1.5},0.01,3},
{{m,0.3},0.01,2},Delimiter,
{{tmax,20},0.01,50},
{{init,{{0,0.5},{0,0.1}}},Locator},ControlPlacement->Left]

Note, to change the starting values click and drag cross-hair icons.

Quasi-equilibrium approximation

Assume dynamics of resource are fast and that it reaches equilbrium

quasiR=Solve[{0==k-β r-α r c},{r}][[1]]

b α r c-m c/.quasiR

-c m+((b c k α)/(c α+β))//Factor

c((b k α-m β-c m α)/(c α+β))
m c((((b k)/m)(α/β)-1-c(α/β))/(c (α/β)+1))
m c((((b k)/m)(α/β)-1-c(α/β))/(1+c(α/β) ))

Get Smith 1963 functional form, which is also the same as a Monod birth rate with a density independent death rate.

((d C)/(d t))=((b k α C )/(β + C α))-C m

Manipulate[
ans=NDSolve[{r'[t]==k-β r[t]-α r[t] c[t],c'[t]==b α r[t] c[t]-m c[t],ca'[t]==-ca[t] m+((b ca[t] k α)/(ca[t] α+β)),r[0]==init[[1,2]],c[0]==init[[2,2]],ca[0]==init[[2,2]]},{r,c,ca},{t,0,tmax}];
Plot[Evaluate[{r[t],c[t],ca[t]}/.ans],{t,0,tmax},PlotRange->{0,3}],
Style["Abiotic Resource & Quasi-Equilibrium Approximation",Bold],Delimiter,
{{k,1},0.01,10},
{{b,1},0.01,3},
{{β,0.8},0.01,3},
{{α,1.5},0.01,3},
{{m,0.3},0.01,2},Delimiter,
{{tmax,20},0.01,50},
{{init,{{0,0.5},{0,0.1}}},Locator},ControlPlacement->Left]

Relationships in quasi-equilibrium model shown graphically

Grid[{{Plot[(( ca[t] )/(ca[t]1+1))-0.5ca[t],{ca[t],0,1.1},Frame->True,FrameLabel->{"C","total population growth"},BaseStyle->{FontFamily->"Helvetica"},ImageSize->Medium],Plot[(( 1)/(ca[t]1+1))-0.5,{ca[t],0,1.3},Frame->True,FrameLabel->{"C","per capita growth"},BaseStyle->{FontFamily->"Helvetica"},ImageSize->Medium]}}]

Options[Plot[(( ca[t] )/(ca[t]1+1))-0.5ca[t],{ca[t],0,1.1},Frame->True]]

Biotic Resource

Full Model

((d R)/(d t))=w R(1-γ R)-α R C
((d C)/(d t))=b α R C-m C

Manipulate[
ans=NDSolve[{r'[t]==w r[t](1-γ r[t])-α r[t] c[t],c'[t]==b α r[t] c[t]-m c[t],r[0]==init[[1,2]],c[0]==init[[2,2]]},{r,c},{t,0,tmax}];
Plot[Evaluate[{r[t],c[t]}/.ans],{t,0,tmax},PlotRange->{0,3}],
Style["Biotic Resource",Bold],Delimiter,
{{w,2},0.01,10},
{{b,0.8},0.01,3},
{{γ,0.8},0.01,3},
{{α,1.5},0.01,3},
{{m,0.3},0.01,2},Delimiter,
{{tmax,30},0.01,50},
{{init,{{0,0.5},{0,0.1}}},Locator},ControlPlacement->Left]

Quasi-equilibrium approximation

Assume dynamics of resource are fast and that it reaches equilbrium

quasiR=Solve[{0==w r(1- γ r)-α r c},{r}][[2]]

Factor[b α r c-m c/.quasiR]

Get Logistic-style function

((d C)/(d t))=(1/(w γ))C (1-((b C (α^2))/(b w α-m w γ)))

Manipulate[
ans=NDSolve[{r'[t]==w r[t](1-γ r[t])-α r[t] c[t],c'[t]==b α r[t] c[t]-m c[t],ca'[t]==-((ca[t] (-b w α+b ca[t] (α^2)+m w γ))/(w γ)),r[0]==init[[1,2]],c[0]==init[[2,2]],ca[0]==init[[2,2]]},{r,c,ca},{t,0,tmax}];
Plot[Evaluate[{r[t],c[t],ca[t]}/.ans],{t,0,tmax},PlotRange->{0,3}],
Style["Biotic Resource & Quasi-Equilibrium Approximation",Bold],Delimiter,
{{w,2},0.01,10},
{{b,0.8},0.01,3},
{{γ,0.8},0.01,3},
{{α,1.5},0.01,3},
{{m,0.3},0.01,2},Delimiter,
{{tmax,30},0.01,50},
{{init,{{0,0.5},{0,0.1}}},Locator},ControlPlacement->Left]

Relationships in quasi-equilibrium model shown graphically

Grid[{{Plot[ca[t] (1-ca[t]),{ca[t],0,1.1},Frame->True,FrameLabel->{"C","total population growth"},BaseStyle->{FontFamily->"Helvetica"},ImageSize->Medium],Plot[1-ca[t],{ca[t],0,1.3},Frame->True,FrameLabel->{"C","per capita growth"},BaseStyle->{FontFamily->"Helvetica"},ImageSize->Medium]}}]

Notice the difference is in the transients (how the population approaches the equilibrium).  In the quasi-equilibrium approximation, the consumer monotonically approaches the equilibrium (i.e. it doesn't wiggle around on its way to the equilibrium).  In essence the quasi-equilibrium approximation assumes that at high consumer densities and low resource densities, the resource level can become negative and avoid these damped cycle approaches to the equilibrium.  In the full model, the resource explicitly has to stay positive.

For example, try make the initial predator density really high.  Drage the cross-bar on the red bar to the top of the figure.  You'll see the resource forced to really low levels and a large transient oscillation.